onLoadInit = function([target_mc:MovieClip]) {}

Appelé une fois les actions de la première image du clip chargé exécutées. Lorsque cet écouteur a été appelé, vous pouvez définir les propriétés, utiliser les méthodes ou encore interagir avec l’animation chargée. Appelle cet écouteur sur un objet d’écoute que vous ajoutez à l’aide de MovieClipLoader.addListener().

La valeur target_mc identifie le clip pour lequel cet appel est effectué. Ce paramètre est particulièrement utile si vous chargez plusieurs fichiers avec le même jeu d’écouteurs.

Disponibilité : ActionScript 1.0 ; Flash Player 7

target_mc:MovieClip [facultatif] - Clip chargé par la méthode MovieClipLoader.loadClip().

L’exemple suivant charge une image dans une occurrence de clip appelée image_mc. Les événements onLoadInit et onLoadComplete permettent de déterminer le temps de chargement de l’image. Les informations s’affichent dans le champ texte appelé timer_txt.

this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
var mclListener:Object = new Object();
mclListener.onLoadStart = function(target_mc:MovieClip) {
     target_mc.startTimer = getTimer();
};
mclListener.onLoadComplete = function(target_mc:MovieClip) {
     target_mc.completeTimer = getTimer();
};
mclListener.onLoadInit = function(target_mc:MovieClip) {
     var timerMS:Number = target_mc.completeTimer-target_mc.startTimer;
     target_mc.createTextField("timer_txt", target_mc.getNextHighestDepth(), 0, target_mc._height, 
target_mc._width, 22);
     target_mc.timer_txt.text = "loaded in "+timerMS+" ms.";
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.helpexamples.com/flash/images/image1.jpg", image_mc);

L’exemple suivant permet de s’assurer qu’une animation a été chargée dans un clip créé lors de l’exécution. L’URL utilisée dans cet exemple n’est là que pour faire une démonstration ; remplacez-la par une URL valide.

this.createEmptyMovieClip("tester_mc", 1);
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
     trace("movie loaded");
}
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.yourserver.com/your_movie.swf", tester_mc);

Si votre fichier SWF comprend un composant de la version 2, utilisez les composants de la version 2 de la classe DepthManager au lieu de la méthode MovieClip.getNextHighestDepth(), utilisée dans cet exemple.

addListener (méthode MovieClipLoader.addListener), loadClip (méthode MovieClipLoader.loadClip), onLoadStart (écouteur événement MovieClipLoader.onLoadStart)