Flash 7 - AS2.

oEcouteur.onMotionFinished = function(tw:Tween):Void {
  // vos instructions
}

• tw : une référence qui cible l’instance de la Tween qui émet l’événement.

Rien.

événement invoqué lorsque l’interpolation est finie.

Un petit effet de yoyo réalisé grace à onMotionFinished(), il vous suffit de crée un nouveau .fla, de copier coller le code sur un calque et de publier pour en voir l’effet (Attention Flash7 - AS2 dans les parametres de publication).

// import de la classe Tween et de la fonction d'interpolation Strong
 
import mx.transitions.* ; // package contenant la classe Tween
 
import mx.transitions.easing.* ; // package contenant les équations de mouvement (Easing Class)
 
// création d'un clip et tracage d'un carré
var mc:MovieClip = this.createEmptyMovieClip("mcUnClip", this.getNextDepth());
with (mc) {
	lineStyle(2, 0x999999, 100);
	moveTo(0, 0);
	lineTo(50, 0);
	lineTo(50, 50);
	lineTo(0, 50);
	lineTo(0, 0);
}
// création objet d'écoute
var oEcouteur:Object = new Object();
oEcouteur.onMotionFinished = function( tw:Tween ):Void {
     // change la fonction de l'interpolation (accéleration)
     tw.func = Strong.easeIn;
 
     // Relance l'interpolation vers sa valeur de départ.
     tw.yoyo();
 
     // enlever l'objet de la liste des écouteurs de l'instance de la classe Tween
     tw.removeListener(this) ;
};
// création d'un Tween (décélération)
var twX:Tween = new Tween(mc, "_y", Strong.easeOut, this._x, 200, 1.5, true);
// abonnement de oEcouteur à l'objet twX
twX.addListener(oEcouteur);

Tween.addListener(), Tween.removeListener(), Tween.onMotionChanged, Tween.onMotionLooped, Tween.onMotionResumed, Tween.onMotionStarted, Tween.onMotionStopped